手写 Loader：开启保护模式与分页虚拟内存

手写 Loader，开启保护模式与虚拟内存#

Loader 从 MBR 手中接过接力棒后，便可以为加载和运行现代内核做准备了，即实现以下任务和能力：

初始化 GDT 并进入保护模式，突破实模式 1MB 内存空间的牢笼，这是加载现代内核的前提
初始化 kernel 页目录和页表，开启分页功能（虚拟内存），解锁现代内核虚拟内存管理的能力
加载并进入内核

在 Loader 中进入保护模式#

上一章实现了打印 Loader 字符串的程序，现在需要将其改造成进入保护模式再打印 Loader 的程序。在 CPU 工作模式 - 实模式/保护模式以及长模式的保护模式一节中，我们了解到段描述符是一个 8 字节（64 位）的结构体，存储段的基地址、段限长（大小）以及访问权限等信息。进入保护模式其实就是定义系统全局的数据段与代码段，然后通过 lgdt 指令加载它，最后将 CR0 寄存器的第 0 位置 1 即可：

1
bits 16
2
org 0x8000
3

4
; this is how constants are defined
5
VIDEO_MEMORY equ 0xb8000
6
WHITE_ON_BLACK equ 0x0f ; the color byte for each character
7

8
    mov bp, 0x7c00 ; set the stack
9
    mov sp, bp
10

11
    ; 清空屏幕
12
    call cls
13

14
    mov bx, MSG_REAL_MODE
15
    call print ; This will be written after the BIOS messages
16

17
    call switch_to_pm
18
    jmp $ ; this will actually never be executed
19

20
gdt_start: ; don't remove the labels, they're needed to compute sizes and jumps
21
    ; the GDT starts with a null 8-byte
22
    dd 0x0 ; 4 byte
23
    dd 0x0 ; 4 byte
24

25
; GDT for code segment. base = 0x00000000, length = 0xfffff
26
; for flags, refer to os-dev.pdf document, page 36
27
gdt_code:
28
    dw 0xffff    ; segment length, bits 0-15
29
    dw 0x0       ; segment base, bits 0-15
30
    db 0x0       ; segment base, bits 16-23
31
    db 10011010b ; flags (8 bits)
32
    db 11001111b ; flags (4 bits) + segment length, bits 16-19
33
    db 0x0       ; segment base, bits 24-31
34

35
; GDT for data segment. base and length identical to code segment
36
; some flags changed, again, refer to os-dev.pdf
37
gdt_data:
38
    dw 0xffff
39
    dw 0x0
40
    db 0x0
41
    db 10010010b
42
    db 11001111b
43
    db 0x0
44

45
gdt_end:
46

47
; GDT descriptor
48
gdt_descriptor:
49
    dw gdt_end - gdt_start - 1 ; size (16 bit), always one less of its true size
50
    dd gdt_start ; address (32 bit)
51

52
; define some constants for later use
53
CODE_SEG equ gdt_code - gdt_start
54
DATA_SEG equ gdt_data - gdt_start
55

56
MSG_REAL_MODE db "Started in 16-bit real mode", 0
57
MSG_PROT_MODE db "Loaded 32-bit protected mode", 0
58

59
switch_to_pm:
60
    cli ; 1. disable interrupts
61
    lgdt [gdt_descriptor] ; 2. load the GDT descriptor
62
    mov eax, cr0
63
    or eax, 0x1 ; 3. set 32-bit mode bit in cr0
64
    mov cr0, eax
65
    jmp CODE_SEG:init_pm ; 4. far jump by using a different segment
66

67
print:
68
    pusha
69

70
; keep this in mind:
71
; while (string[i] != 0) { print string[i]; i++ }
72

73
; the comparison for string end (null byte)
74
print_start:
75
    mov al, [bx] ; 'bx' is the base address for the string
76
    cmp al, 0
77
    je done
78

79
    ; the part where we print with the BIOS help
80
    mov ah, 0x0e
81
    int 0x10 ; 'al' already contains the char
82

83
    ; increment pointer and do next loop
84
    add bx, 1
85
    jmp print_start
86

87
done:
88
    popa
89
    ret
90

91
print_nl:
92
    pusha
93

94
    mov ah, 0x0e
95
    mov al, 0x0a ; newline char
96
    int 0x10
97
    mov al, 0x0d ; carriage return
98
    int 0x10
99

100
    popa
101
    ret
102

103
; 清屏，并将屏幕设置为黑底白字
104
cls:
105
    mov ax, 0x0600       ; ah=06h(滚动窗口功能), al=00h(清空整个窗口)
106
    mov bx, 0x0700       ; bh=07h(空白行的显示属性: 黑底白字)
107
    mov cx, 0            ; ch=00h(左上角行号=0), cl=00h(左上角列号=0)
108
    mov dx, 184fh        ; dh=18h(右下角行号=24), dl=4fh(右下角列号=79)
109
    int 10h              ; 调用bios中断
110

111
    ; 重置光标到 (0,0)
112
    mov ah, 0x02
113
    xor dx, dx          ; DH=0, DL=0
114
    mov bh, 0
115
    int 0x10
116
    ret
117

118
[bits 32]
119
init_pm: ; we are now using 32-bit instructions
120
    mov ax, DATA_SEG ; 5. update the segment registers
121
    mov ds, ax
122
    mov ss, ax
123
    mov es, ax
124
    mov fs, ax
125
    mov gs, ax
126

127
    mov ebp, 0x90000 ; 6. update the stack right at the top of the free space
128
    mov esp, ebp
129

130
    call BEGIN_PM ; 7. Call a well-known label with useful code
131

132
BEGIN_PM: ; after the switch we will get here
133
    mov ebx, MSG_PROT_MODE
134
    call print_string_pm ; Note that this will be written at the top left corner
135
    jmp $
136

137
print_string_pm:
138
    pusha
139
    mov edx, VIDEO_MEMORY
140

141
print_string_pm_loop:
142
    mov al, [ebx] ; [ebx] is the address of our character
143
    mov ah, WHITE_ON_BLACK
144

145
    cmp al, 0 ; check if end of string
146
    je print_string_pm_done
147

148
    mov [edx], ax ; store character + attribute in video memory
149
    add ebx, 1 ; next char
150
    add edx, 2 ; next video memory position
151

152
    jmp print_string_pm_loop
153

154
print_string_pm_done:
155
    popa
156
    ret

将上面的代码编译并通过 dd 插入到 loader.vhd 后运行，可以观察到下面的结果： pm-mode

整理代码#

无论是进入保护模式时定义的 GDT，还是开启分页需要定义的页表，都涉及大量数据结构与常量。为了避免这些干扰项，使代码逻辑更加清晰，可以将这些定义放在**包含文件（.inc）**中，在主代码文件中使用 %include 包含进来。

首先定义包含文件 bootmacros.inc：

1
; -----------------------------------------------------------------------
2
; bootmacros.inc — Boot constants, GDT macros, selectors, and paging helpers
3
; NASM syntax
4
; -----------------------------------------------------------------------
5

6
; =================================================================================
7
; 内存布局常量
8
; =================================================================================
9
MBR_BASE_ADDR        equ 0x7C00      ; BIOS加载MBR的物理地址
10
LOADER_BASE_ADDR     equ 0x8000      ; 引导程序加载地址
11
LOADER_START_SECTOR  equ 1           ; 引导程序起始扇区
12

13
; =================================================================================
14
; 视频内存常量
15
; =================================================================================
16
VIDEO_MEMORY         equ 0xB8000     ; 文本模式视频内存地址
17
WHITE_ON_BLACK       equ 0x0F        ; 黑底白字属性字节
18

19
; ================================================================================
20
; GDT 结构宏定义
21
; ================================================================================
22
; 每个 GDT 描述符占 8 字节，总结构如下（按低地址到高地址）：
23
;
24
;  31                                16 15                                   0
25
;  +------------------------------------+------------------------------------+
26
;  |         Base[15:0]                 |         Limit[15:0]                |
27
;  +------------------------------------+------------------------------------+
28
;  |  Base[23:16]  | Access Byte        | Flags | Limit[19:16] | Base[31:24] |
29
;  +------------------------------------+------------------------------------+
30
;
31
; Access Byte （第 5 字节）控制段的类型、存在、特权等；
32
; Flags （第 6 字节高 4 位）控制段粒度、操作数大小、64 位模式等。
33
;
34
; ------------------------------------------------------------------------------
35
; Intel 手册：Descriptor Type Fields
36
;   Access Byte (bits 8..15)    → 控制"段类型"
37
;   Flags (bits 20..23)         → 控制"段属性"
38
; ================================================================================
39

40

41
; ================================================================================
42
; [1] Access Byte 位布局（8 bits）
43
; ================================================================================
44
; bit | 名称 | 说明
45
; ----+------+--------------------------------------------------------------
46
;  7  | P    | 段存在位 (1=有效)
47
; 6-5 | DPL  | 特权级别（0=最高, 3=最低）
48
;  4  | S    | 描述符类型 (1=代码/数据, 0=系统段)
49
; 3-0 | TYPE | 段类型（取决于S=1或S=0）
50

51
; ------------------------------------------------------------------------------
52
; [Access Byte] 位定义（保持互斥且可组合）
53
; ------------------------------------------------------------------------------
54

55
; (bit 7)
56
ACCESS_P          equ 0x80        ; P=1, 段存在于内存
57

58
; (bits 6-5) 特权级（DPL）
59
ACCESS_DPL0       equ 0x00        ; CPL=0（内核）
60
ACCESS_DPL1       equ 0x20        ; CPL=1
61
ACCESS_DPL2       equ 0x40        ; CPL=2
62
ACCESS_DPL3       equ 0x60        ; CPL=3（用户）
63

64
; (bit 4)
65
ACCESS_S_CODEDATA equ 0x10        ; S=1, 普通代码/数据段
66
ACCESS_S_SYSTEM   equ 0x00        ; S=0, 系统段 (TSS, LDT等)
67

68
; (bits 3-0) TYPE 字段
69
; --- 数据段类型（S=1 且 TYPE[3]=0）---
70
ACCESS_DATA_RD    equ 0x00        ; 只读
71
ACCESS_DATA_RDA   equ 0x01        ; 只读, 已访问
72
ACCESS_DATA_RW    equ 0x02        ; 可读写
73
ACCESS_DATA_RWA   equ 0x03        ; 可读写, 已访问
74
ACCESS_DATA_EXP   equ 0x04        ; 向下扩展，只读
75
ACCESS_DATA_EXPW  equ 0x06        ; 向下扩展，可写
76

77
; --- 代码段类型（S=1 且 TYPE[3]=1）---
78
ACCESS_CODE_X     equ 0x08        ; 只执行
79
ACCESS_CODE_XR    equ 0x0A        ; 可执行+可读（最常用）
80
ACCESS_CODE_XC    equ 0x0C        ; 一致代码段（低特权可执行）
81
ACCESS_CODE_XRC   equ 0x0E        ; 可执行+可读+一致
82

83
; ------------------------------------------------------------------------------
84
; 常用组合（可直接使用）
85
; ------------------------------------------------------------------------------
86
ACCESS_CODE32_KERNEL equ ACCESS_P | ACCESS_DPL0 | ACCESS_S_CODEDATA | ACCESS_CODE_XR
87
ACCESS_DATA32_KERNEL equ ACCESS_P | ACCESS_DPL0 | ACCESS_S_CODEDATA | ACCESS_DATA_RW
88
ACCESS_CODE32_USER   equ ACCESS_P | ACCESS_DPL3 | ACCESS_S_CODEDATA | ACCESS_CODE_XR
89
ACCESS_DATA32_USER   equ ACCESS_P | ACCESS_DPL3 | ACCESS_S_CODEDATA | ACCESS_DATA_RW
90

91

92
; ================================================================================
93
; [2] Flags 位布局（高 4 位 bits 20..23）
94
; ================================================================================
95
; bit | 名称 | 说明
96
; ----+------+--------------------------------------------------------------
97
;  7-4| Flags高4位  | G / D / L / AVL
98
;  3-0| Limit高4位  | 段界限高4位（由 GDT_ENTRY 宏补充）
99
;
100
; Flags字段高4位（即 descriptor 第6字节的高半字节）：
101
;    7 6 5 4
102
;    G D L AVL
103
;
104
; ------------------------------------------------------------------------------
105
; [Flags] 位定义（高4位部分）
106
; ------------------------------------------------------------------------------
107

108
FLAGS_G_4K      equ 0x8     ; G=1, 粒度=4KB
109
FLAGS_G_BYTE    equ 0x0     ; G=0, 粒度=1B
110

111
FLAGS_D_32      equ 0x4     ; D=1, 32位默认操作数大小
112
FLAGS_D_16      equ 0x0     ; D=0, 16位默认操作数大小
113

114
FLAGS_L_64      equ 0x2     ; L=1, 64位代码段（仅 IA-32e 模式）
115
FLAGS_L_32      equ 0x0     ; L=0, 32位段
116

117
FLAGS_AVL       equ 0x1     ; AVL=1, 软件可用位（一般置0）
118

119
; ------------------------------------------------------------------------------
120
; 常用组合
121
; ------------------------------------------------------------------------------
122
FLAGS_4K_32BIT  equ FLAGS_G_4K | FLAGS_D_32 | FLAGS_L_32
123
FLAGS_4K_64BIT  equ FLAGS_G_4K | FLAGS_L_64
124
FLAGS_BYTE_16BIT equ FLAGS_G_BYTE | FLAGS_D_16
125

126

127
; ================================================================================
128
; [3] 通用常量
129
; ================================================================================
130
DESC_BASE_ZERO   equ 0x00000000
131
DESC_LIMIT_MAX   equ 0xFFFFF     ; 当 G=4K 时, 表示 4GB 空间
132

133

134
; ================================================================================
135
; [4] GDT Entry 构造宏
136
; ================================================================================
137
; GDT_ENTRY base, limit, access_byte, flags_nibble
138
; 输出: 共6条指令，生成完整8字节描述符
139
; ------------------------------------------------------------------------------
140
%macro GDT_ENTRY 4
141
    dw (%2 & 0xFFFF)                                 ; Limit[15:0]
142
    dw (%1 & 0xFFFF)                                 ; Base[15:0]
143
    db ((%1 >> 16) & 0xFF)                           ; Base[23:16]
144
    db %3                                            ; Access Byte
145
    db (((%2 >> 16) & 0x0F) | ((%4 & 0x0F) << 4))    ; Flags高4位 | Limit高4位
146
    db ((%1 >> 24) & 0xFF)                           ; Base[31:24]
147
%endmacro
148

149

150
; ================================================================================
151
; [5] 标准 GDT 定义（最小可运行）
152
; ================================================================================
153
%macro DEFINE_STANDARD_GDT 0
154
gdt_start:
155
    ; Null Descriptor（必须存在）
156
    GDT_ENTRY 0, 0, 0, 0
157

158
    ; 内核代码段: base=0, limit=4GB, 32位, 粒度4K
159
    GDT_ENTRY DESC_BASE_ZERO, DESC_LIMIT_MAX, ACCESS_CODE32_KERNEL, FLAGS_4K_32BIT
160

161
    ; 内核数据段
162
    GDT_ENTRY DESC_BASE_ZERO, DESC_LIMIT_MAX, ACCESS_DATA32_KERNEL, FLAGS_4K_32BIT
163

164
    ; 视频段 (0xB8000, limit约4KB)
165
    GDT_ENTRY 0x000B8000, 0x07FF, ACCESS_DATA32_KERNEL, FLAGS_G_BYTE
166

167
gdt_end:
168

169
gdt_descriptor:
170
    dw gdt_end - gdt_start - 1
171
    dd gdt_start
172
%endmacro
173

174

175
; ================================================================================
176
; [6] 段选择子定义
177
; ================================================================================
178
RPL0    equ 0
179
RPL3    equ 3
180
TI_GDT  equ 0
181
TI_LDT  equ 4
182

183
SELECTOR_NULL     equ (0 << 3) + TI_GDT + RPL0
184
SELECTOR_CODE32   equ (1 << 3) + TI_GDT + RPL0
185
SELECTOR_DATA32   equ (2 << 3) + TI_GDT + RPL0
186
SELECTOR_VIDEO    equ (3 << 3) + TI_GDT + RPL0
187
SELECTOR_UCODE32  equ (4 << 3) + TI_GDT + RPL3
188
SELECTOR_UDATA32  equ (5 << 3) + TI_GDT + RPL3
189

190
; =================================================================================
191
; 栈设置宏
192
; =================================================================================
193
; 将栈指针设置到MBR_BASE_ADDR
194
; 注意: 只有512字节的栈空间，使用时需谨慎
195
;
196
; 使用示例:
197
;   SET_STACK_AT_MBR
198
%macro SET_STACK_AT_MBR 0
199
    xor ax, ax
200
    mov ss, ax
201
    mov sp, MBR_BASE_ADDR
202
%endmacro
203

204
%macro SET_STACK_AT_PM 0
205
    mov esp, 0x00090000
206
    mov ebp, esp
207
%endmacro
208

209
; =================================================================================
210
; ATA 相关
211
; =================================================================================
212

213
ATA_PRIMARY_BASE      equ 0x1F0
214

215
; =================================================================================
216
; 分页相关常量（节选，后文 enable_page 中使用）
217
; =================================================================================
218
PAGE_SIZE         equ 0x1000       ; 标准页大小 (4KB)
219

220
PAGE_DIR_PHYISCAL_ADDR            equ  0x100000 + PAGE_SIZE   ; 页目录物理地址 0x101000
221
PAGE_DIR_PHYSICAL_ADDR            equ  PAGE_DIR_PHYISCAL_ADDR  ; 拼写纠正别名
222
PAGE_DIR_VIRTUAL_ADDR             equ  0xC0701000              ; 页目录虚拟地址
223
PAGE_TABLES_VIRTUAL_ADDR_START    equ  0xC0400000              ; 页表区虚拟起点
224

225
; 页表条目标志位（与上文 PDE/PTE 位布局对应）
226
PTE_PRESENT       equ 1 << 0       ; 位0 存在位
227
PTE_WRITE         equ 1 << 1       ; 位1 写允许
228
PTE_USER          equ 1 << 2       ; 位2 用户访问
229
PTE_PWT           equ 1 << 3       ; 位3 页级写通过
230
PTE_PCD           equ 1 << 4       ; 位4 页级缓存禁用
231
PTE_ACCESSED      equ 1 << 5       ; 位5 访问位
232
PTE_DIRTY         equ 1 << 6       ; 位6 脏位
233
PTE_PAT           equ 1 << 7       ; 位7 页属性表
234
PTE_GLOBAL        equ 1 << 8       ; 位8 全局页
235

236
; =================================================================================
237
; CR0 位掩码（节选）
238
; =================================================================================
239
CR0_PE          equ 1 << 0      ; Protection Enable
240
CR0_PG          equ 1 << 31     ; PaGing
241

242
; =================================================================================
243
; 内核空间常量（节选）
244
; =================================================================================
245
KERNEL_SPACE_START              equ   0xC0000000
246

247
; =================================================================================
248
; 结束
249
; =================================================================================

进入保护模式后，实模式下方便的 BIOS 中断便不可再用，所以需要在保护模式下实现一些实用功能：

文本打印
光标控制
磁盘读写
…

将它们实现到 pm_utils.S 中，同样通过 include 指令加载：

1
; -----------------------------------------------------------------------
2
; pm_utils.S — Protected mode utility library (fixed & optimized version)
3
; NASM syntax, 32-bit protected-mode helpers
4
; -----------------------------------------------------------------------
5

6
%define SCREEN_WIDTH     80
7
%define SCREEN_HEIGHT    25
8

9
%define ATA_PRIMARY_BASE     0x1F0
10
%define ATA_PRIMARY_CONTROL  0x3F6
11

12
%define WHITE_ON_BLACK 0x0F
13

14
section .data
15
cursor_row: dd 0
16
cursor_col: dd 0
17

18
section .text
19

20
; ======================================================================
21
; 光标管理函数 (cdecl)
22
; ======================================================================
23

24
set_cursor_pos:
25
    ; [esp+4] = row, [esp+8] = col
26
    mov eax, [esp + 4]
27
    mov [cursor_row], eax
28
    mov eax, [esp + 8]
29
    mov [cursor_col], eax
30
    ret
31

32
get_cursor_pos:
33
    mov eax, [cursor_row]
34
    mov edx, [cursor_col]
35
    ret
36

37
move_cursor_forward:
38
    ; [esp+4] = count
39
    push ebp
40
    mov ebp, esp
41
    mov eax, [ebp + 8]      ; count
42
    mov ecx, [cursor_row]
43
    mov edx, [cursor_col]
44
    add edx, eax
45

46
.fixup:
47
    cmp edx, SCREEN_WIDTH
48
    jl .store
49
    sub edx, SCREEN_WIDTH
50
    inc ecx
51
    jmp .fixup
52
.store:
53
    mov [cursor_row], ecx
54
    mov [cursor_col], edx
55
    pop ebp
56
    ret
57

58
cursor_newline:
59
    ; 行 +1，列 = 0，防止越界（不自动滚屏）
60
    mov eax, [cursor_row]
61
    inc eax
62
    cmp eax, SCREEN_HEIGHT
63
    jb .ok
64
    mov eax, SCREEN_HEIGHT - 1
65
.ok:
66
    mov [cursor_row], eax
67
    mov dword [cursor_col], 0
68
    ret
69

70
; ======================================================================
71
; 硬件光标
72
; ======================================================================
73

74
set_hardware_cursor:
75
    push ebp
76
    mov  ebp, esp
77
    push eax
78
    push ebx
79
    push ecx
80
    push edx
81

82
    mov eax, [ebp + 8]      ; row
83
    mov ecx, SCREEN_WIDTH
84
    xor edx, edx
85
    mul ecx
86
    add eax, [ebp + 12]     ; + col
87

88
    mov dx, 0x3D4
89
    mov bx, ax              ; bx = cell index (word)
90

91
    mov al, 0x0E
92
    out dx, al
93
    inc dx
94
    mov al, bh
95
    out dx, al
96

97
    dec dx
98
    mov al, 0x0F
99
    out dx, al
100
    inc dx
101
    mov al, bl
102
    out dx, al
103

104
    pop edx
105
    pop ecx
106
    pop ebx
107
    pop eax
108
    pop ebp
109
    ret
110

111
sync_hardware_cursor:
112
    ; 使用当前软光标同步硬件光标
113
    mov eax, [cursor_row]
114
    mov edx, [cursor_col]
115
    push edx
116
    push eax
117
    call set_hardware_cursor
118
    add esp, 8
119
    ret
120

121
; ======================================================================
122
; 屏幕控制
123
; ======================================================================
124

125
clear_screen:
126
    push ebx
127
    push ecx
128
    push edi
129
    push esi
130

131
    mov ecx, SCREEN_WIDTH * SCREEN_HEIGHT
132
    mov bx, 0x0720          ; word: attr + ' '
133
    xor edi, edi
134
    mov esi, ecx
135

136
.clear_loop:
137
    mov [gs:edi], bx
138
    add edi, 2
139
    dec esi
140
    jnz .clear_loop
141

142
    pop esi
143
    pop edi
144
    pop ecx
145
    pop ebx
146

147
    mov dword [cursor_row], 0
148
    mov dword [cursor_col], 0
149

150
    push 0
151
    push 0
152
    call set_hardware_cursor
153
    add esp, 8
154
    ret
155

156
; ======================================================================
157
; 打印功能
158
; ======================================================================
159

160
; get_vram_addr - 返回字节偏移到 eax（字节偏移，用于 [gs:eax] 访问）
161
get_vram_addr:
162
    mov eax, [cursor_row]
163
    mov ecx, SCREEN_WIDTH
164
    xor edx, edx
165
    mul ecx
166
    add eax, [cursor_col]
167
    shl eax, 1              ; bytes
168
    ret
169

170
print_char:
171
    push ebp
172
    mov ebp, esp
173
    push edi
174
    push eax
175
    push ebx
176
    push ecx
177
    push edx
178

179
    ; 取参数（只用低字节）
180
    mov  al, byte [ebp + 8]    ; char
181
    mov  bl, byte [ebp + 12]   ; attr
182

183
    ; 把 char/attr 合成 word，保存到 BX，避免被后续计算覆盖
184
    mov  ah, bl                ; AH = attr, AL = char
185
    mov  bx, ax                ; BX = AX(=char+attr)
186

187
    ; 计算显存偏移 (用 EAX 重新计算，不影响 BX)
188
    mov eax, [cursor_row]
189
    mov ecx, SCREEN_WIDTH
190
    xor edx, edx
191
    mul ecx
192
    add eax, [cursor_col]
193
    shl eax, 1
194
    mov edi, eax
195

196
    ; 写显存
197
    mov ax, bx
198
    mov [gs:edi], ax
199

200
    ; 更新光标
201
    inc dword [cursor_col]
202
    cmp dword [cursor_col], SCREEN_WIDTH
203
    jl .done
204
    mov dword [cursor_col], 0
205
    inc dword [cursor_row]
206
    cmp dword [cursor_row], SCREEN_HEIGHT
207
    jl .done
208
    mov dword [cursor_row], SCREEN_HEIGHT - 1
209

210
.done:
211
    pop edx
212
    pop ecx
213
    pop ebx
214
    pop eax
215
    pop edi
216
    pop ebp
217
    ret
218

219
print_string:
220
    push ebp
221
    mov ebp, esp
222
    push esi
223
    push edi
224
    push ebx
225

226
    mov esi, [ebp + 8]        ; string
227
    mov bl, [ebp + 12]        ; attr
228

229
    mov eax, [cursor_row]
230
    mov ecx, SCREEN_WIDTH
231
    xor edx, edx
232
    mul ecx                   ; eax = row * SCREEN_WIDTH
233
    add eax, [cursor_col]     ; eax = 偏移（单位：字符）
234

235
    mov edi, eax
236
    shl edi, 1                ; 每个字符 2 字节
237
    mov ah, bl                ; attr 在 ah
238

239
.print_loop:
240
    lodsb
241
    test al, al
242
    jz .done
243
    cmp al, 10                ; '\n'
244
    je .newline
245

246
    mov [gs:edi], ax
247
    add edi, 2
248

249
    ; 更新 cursor_col
250
    inc dword [cursor_col]
251
    cmp dword [cursor_col], SCREEN_WIDTH
252
    jl .print_loop
253

254
.newline:
255
    mov dword [cursor_col], 0
256
    inc dword [cursor_row]
257
    mov eax, [cursor_row]
258
    mov ecx, SCREEN_WIDTH
259
    xor edx, edx
260
    mul ecx
261
    shl eax, 1
262
    mov edi, eax
263
    jmp .print_loop
264

265
.done:
266
    pop ebx
267
    pop edi
268
    pop esi
269
    pop ebp
270
    ret
271

272
println:
273
    push ebp
274
    mov ebp, esp
275

276
    ; 取出参数
277
    mov eax, [ebp + 8]      ; string
278
    mov edx, [ebp + 12]     ; color
279

280
    ; 正确传递给 print_string
281
    push edx
282
    push eax
283
    call print_string
284
    add esp, 8
285

286
    call cursor_newline
287
    call sync_hardware_cursor
288

289
    pop ebp
290
    ret
291

292
; ======================================================================
293
; 打印十六进制/十六进制32
294
; ======================================================================
295

296
; print_hex8: [esp+4]=value(byte), [esp+8]=attr(byte)
297
print_hex8:
298
    push ebp
299
    mov  ebp, esp
300
    push eax
301
    push ebx
302
    push ecx
303
    push edx
304

305
    mov  al, byte [ebp + 8]     ; value (low 8 bits)
306
    mov  bl, byte [ebp + 12]    ; attr
307
    mov  dl, al                 ; backup original byte into DL
308

309
    ; ---- high nibble ----
310
    mov  cl, dl
311
    shr  cl, 4
312
    and  cl, 0x0F
313
    cmp  cl, 9
314
    jbe  .h_digit
315
    add  cl, 'A' - 10
316
    jmp  .h_done
317
.h_digit:
318
    add  cl, '0'
319
.h_done:
320
    movzx eax, cl        ; zero-extend ASCII char into EAX
321
    movzx ecx, bl        ; zero-extend attr into ECX
322
    push ecx
323
    push eax
324
    call print_char
325
    add  esp, 8
326

327
    ; ---- low nibble ----
328
    mov  cl, dl
329
    and  cl, 0x0F
330
    cmp  cl, 9
331
    jbe  .l_digit
332
    add  cl, 'A' - 10
333
    jmp  .l_done
334
.l_digit:
335
    add  cl, '0'
336
.l_done:
337
    movzx eax, cl
338
    movzx ecx, bl
339
    push ecx
340
    push eax
341
    call print_char
342
    add  esp, 8
343

344
    pop  edx
345
    pop  ecx
346
    pop  ebx
347
    pop  eax
348
    pop  ebp
349
    ret
350

351
; print_hex32: [esp+4]=value(dword), [esp+8]=attr(byte)
352
print_hex32:
353
    push    ebp
354
    mov     ebp, esp
355
    push    eax
356
    push    ebx
357
    push    ecx
358
    push    edx
359
    push    esi
360
    push    edi
361

362
    mov     eax, [ebp + 8]     ; value
363
    mov     bl, byte [ebp + 12] ; attr
364
    mov     ecx, 8
365

366
.hloop:
367
    mov     edx, eax
368
    shr     edx, 28
369
    and     dl, 0x0F
370

371
    cmp     dl, 9
372
    jbe     .digit
373
    add     dl, 'A' - 10
374
    jmp     .out
375
.digit:
376
    add     dl, '0'
377
.out:
378
    movzx   esi, dl
379
    movzx   edi, bl
380
    push    edi
381
    push    esi
382
    call    print_char
383
    add     esp, 8
384

385
    shl     eax, 4
386
    loop    .hloop
387

388
    pop     edi
389
    pop     esi
390
    pop     edx
391
    pop     ecx
392
    pop     ebx
393
    pop     eax
394
    pop     ebp
395
    ret
396

397
; ======================================================================
398
; 内存操作（标准 prologue/epilogue）
399
; ======================================================================
400

401
memcpy:
402
    ; [esp+4] = dest, [esp+8] = src, [esp+12] = n
403
    push ebp
404
    mov  ebp, esp
405
    push esi
406
    push edi
407
    push ecx
408

409
    mov edi, [ebp + 8]
410
    mov esi, [ebp + 12]
411
    mov ecx, [ebp + 16]
412
    cld
413
    rep movsb
414

415
    pop ecx
416
    pop edi
417
    pop esi
418
    pop ebp
419
    ret
420

421
memset:
422
    ; [esp+4]=dest, [esp+8]=val (byte), [esp+12]=n
423
    push ebp
424
    mov  ebp, esp
425
    push edi
426
    push ecx
427

428
    mov edi, [ebp + 8]      ; dest
429
    mov al, [ebp + 12]      ; val (byte)
430
    mov ecx, [ebp + 16]     ; count
431
    cld
432
    rep stosb
433

434
    pop ecx
435
    pop edi
436
    pop ebp
437
    ret
438

439
; ======================================================================
440
; ATA 磁盘读取 (PIO 模式)
441
; cdecl: [ebp+8]=LBA, [ebp+12]=count, [ebp+16]=buf
442
; 每次读 1 个扇区，循环 count 次
443
; ======================================================================
444
read_disk:
445
    push ebp
446
    mov  ebp, esp
447
    pushad
448

449
    mov esi, [ebp + 8]     ; LBA 起始扇区号
450
    mov edi, [ebp + 12]    ; 扇区数量
451
    mov ebx, [ebp + 16]    ; 目标缓冲区地址
452

453
.next_sector:
454
    ; --------------------------------------
455
    ; 写入扇区数量（每次读1个）
456
    ; --------------------------------------
457
    mov dx, ATA_PRIMARY_BASE + 2
458
    mov al, 1
459
    out dx, al
460

461
    ; --------------------------------------
462
    ; 写入 LBA 地址（低 24 位）
463
    ; --------------------------------------
464
    mov eax, esi
465
    mov dx, ATA_PRIMARY_BASE + 3
466
    out dx, al
467
    shr eax, 8
468
    mov dx, ATA_PRIMARY_BASE + 4
469
    out dx, al
470
    shr eax, 8
471
    mov dx, ATA_PRIMARY_BASE + 5
472
    out dx, al
473
    shr eax, 8
474
    and al, 0x0F
475
    or  al, 0xE0             ; 主盘 + LBA 模式
476
    mov dx, ATA_PRIMARY_BASE + 6
477
    out dx, al
478

479
    ; --------------------------------------
480
    ; 发送读命令 READ SECTOR (0x20)
481
    ; --------------------------------------
482
    mov dx, ATA_PRIMARY_BASE + 7
483
    mov al, 0x20
484
    out dx, al
485

486
.wait_ready:
487
    in  al, dx                       ; 状态寄存器
488
    test al, 0x80                    ; BSY=1 ? 忙碌中？
489
    jnz  .wait_ready
490
    test al, 0x08                    ; DRQ=1 ? 数据准备好？
491
    jz   .wait_ready
492

493
    ; ----------------------- 读一个扇区 -----------------------
494
    mov dx, ATA_PRIMARY_BASE + 0     ; 数据端口
495
    mov ecx, 256                     ; 每扇区 256 words = 512B
496
.read_word:
497
    in  ax, dx
498
    mov [ebx], ax
499
    add ebx, 2
500
    loop .read_word
501

502
    ; ----------------------- 准备下一个扇区 -----------------------
503
    inc esi       ; LBA++
504
    dec edi       ; 扇区数--
505
    jnz .next_sector
506

507
.done:
508
    popad
509
    pop ebp
510
    ret

这样 loader.S 即可简化为：

1
[bits 16]
2
org 0x8000
3

4
%include "../common/bootmacros.inc"
5

6
_start:
7
    jmp loader_start
8

9
; 定义 GDT
10
DEFINE_STANDARD_GDT
11

12
loader_start:
13
    cli
14
    xor ax, ax
15
    mov ds, ax
16
    mov es, ax
17
    mov fs, ax
18
    mov gs, ax
19

20
    SET_STACK_AT_MBR
21

22
    call cls
23
    mov bx, MSG_REAL_MODE
24
    call print_bios
25

26
    ; 启用A20地址线
27
    in al, 0x92
28
    or al, 0000_0010b
29
    out 0x92, al
30

31
    ; 加载GDT并进入保护模式
32
    lgdt [gdt_descriptor]
33
    ; 设置 PE
34
    mov eax, cr0
35
    or eax, 1
36
    mov cr0, eax
37

38
    ; 远跳刷新CS
39
    jmp SELECTOR_CODE32:init_pm
40

41
; ------------------------------
42
; BIOS文本输出
43
; ------------------------------
44
print_bios:
45
    pusha
46
.loop:
47
    mov al, [bx]
48
    test al, al
49
    jz .done
50
    mov ah, 0x0e
51
    int 0x10
52
    inc bx
53
    jmp .loop
54
.done:
55
    popa
56
    ret
57

58
cls:
59
    mov ax, 0x0600
60
    mov bx, 0x0700
61
    mov cx, 0
62
    mov dx, 184Fh
63
    int 0x10
64
    mov ah, 0x02
65
    xor dx, dx
66
    xor bh, bh
67
    int 0x10
68
    ret
69

70
MSG_REAL_MODE db "Started in 16-bit real mode (BIOS)",0
71
MSG_PROT_MODE db "Now in 32-bit protected mode (direct video)",0
72

73
; ------------------------------
74
; 保护模式初始化
75
; ------------------------------
76
[bits 32]
77

78
%include "../common/lib/pm_utils.S"
79

80
init_pm:
81
    mov ax, SELECTOR_DATA32
82
    mov ds, ax
83
    mov es, ax
84
    mov fs, ax
85
    mov ss, ax
86
    mov ax, SELECTOR_VIDEO
87
    mov gs, ax
88

89
    ; 切换栈
90
    SET_STACK_AT_PM
91

92
    call clear_screen
93

94
    ; 打印保护模式信息
95
    push 0x0F
96
    push MSG_PROT_MODE
97
    call println
98
    add esp, 8
99

100
    cli
101
.hang:
102
    hlt
103
    jmp .hang

开启虚拟内存分页#

虚拟内存技术简介与使用#

虚拟内存技术把线性地址的内存空间按固定大小（4 KiB/2 MiB/1 GiB）切成页，然后把物理内存也切成同样大小的页框。用多级页表 + MMU 完成虚拟页号 → 物理页框号的映射，缺页时由 OS 动态换入/换出。

在 32 位环境下，32 位的地址可以表达 4GB 的虚拟内存空间。开启 4KiB 分页后，CPU 会把虚拟地址分为三部分：高 10 位是页目录索引（Page Directory Index，PDI），可定位 $2^{10}=1024$ 项页目录；中间 10 位是页表索引（Page Table Index，PTI），可定位 $2^{10}=1024$ 项页表；最后 12 位是页内偏移（Page Offset），定位页内的具体字节。

位范围	字段	宽度
31 - 22	页目录索引（PDI）	10 bit
21 - 12	页表索引（PTI）	10 bit
11 - 0	页内偏移（Offset）	12 bit

页目录和页表都是 4 字节的结构，1024 个页目录项中都有 1024 项页表，所以一共仅需 1024 × 1024 × 4 = 4MB 的物理内存空间即可存储 4GB 虚拟地址 → 物理地址的映射关系： paging

页目录项（PDE，4KB 页）：

位数	名称	作用
0	P（Present）	该页表是否存在
1	R/W（Read/Write）	可读写权限
2	U/S（User/Supervisor）	用户态/内核态访问权限
3	PWT（Page Write Through）	页表本身的写透传缓存策略
4	PCD（Page Cache Disable）	是否禁用页表缓存
5	A（Accessed）	是否被访问过
6	保留	4KB PDE 保留位，应为 0
7	PS（Page Size）	0 表示指向页表，1 表示 4MB 大页
8	G（Global）	全局页（开启 PGE 时 TLB 不失效）
9–11	OS 可用	供操作系统自由使用
12–31	页表基址高 20 位	指向页表的物理地址（4KB 对齐）

页表项（PTE）：

位数	名称	作用
0	P（Present）	该页是否映射
1	R/W（Read/Write）	是否可写
2	U/S（User/Supervisor）	用户态/内核态权限
3	PWT（Page Write Through）	页的写透传缓存策略
4	PCD（Page Cache Disable）	是否禁用该页缓存
5	A（Accessed）	是否访问过
6	D（Dirty）	是否被写过（仅对可写页有效）
7	PAT（Page Attribute Table）	页属性表索引（无 PAT 时作保留位）
8	G（Global）	全局页（开启 PGE 时 TLB 不失效）
9–11	可用位	供操作系统自由使用
12–31	页框基址高 20 位	指向实际物理页地址（4KB 对齐）

PDE 与 PTE 的低 8 位布局很相似，区别主要在第 6、7 位：PDE 第 6 位保留、第 7 位是 PS（决定指向页表还是大页），PTE 第 6 位是 D（脏位）、第 7 位是 PAT。bootmacros.inc 中的 PTE_GLOBAL（1<<8）等标志位就是按上表第 8 位定义的。

当开启虚拟内存分页后，CPU 会从虚拟地址进行取指/取数，经历以下流程：

先从 MMU 中查询 TLB，如果命中则直接得到物理地址

若 TLB Miss，则会查询 2 级页表，首先从 CR3 中获取页目录的物理基址

然后通过页目录的物理基址 + VA 中高 10 位的页目录索引 × 4 得到页目录项索引的物理地址，从该地址中的页目录结构的高 20 位中得到页表项物理基址（）

由页表项物理基址 + VA 中 10 位的页表索引 × 4 得到页表项的物理地址，从该地址中的页表结构的高 20 位中能得到物理页框基址（）

最后由物理页框基址 + VA 中低 12 位的页内偏移即可得到，同时会将这个映射关系（虚拟页号 → 物理页框）写入 TLB 缓存

要开启分页，首先需要在物理地址空间中划分出 4MB 空间用来存储映射关系，然后拿出一个 4KB 物理帧（frame）作为页目录。再为内核创建所需的页表项，最后把划分给页目录的物理帧作为页目录基址载入 CR3，以及把 CR0.PG 置 1 即可开启分页。

页目录规划#

1MB 以下的空间已经被实模式规划征用，所以用来存储页目录的物理帧可以从 0x100000 开始。

选择使用 0x100000 后面的第一个帧存储第一个 page table，它用来映射 0 ～ 1MB 低内存
第二个帧即 0x100000 + 4KB 用来存储页目录
PDE 索引按虚拟地址高 10 位划分：PDE[0] ~ PDE[767] 对应 0x00000000 ~ 0xBFFFFFFF 的用户空间，PDE[768] ~ PDE[1023] 对应 0xC0000000 ~ 0xFFFFFFFF 的内核空间。其中 PDE[0] 与 PDE[768] 指向同一张低 1MB 页表，使得内核空间起始处仍然能看到低 1MB 物理内存（包括显存、bootloader 数据等）
为了方便内核能操作和修改页目录以及页表项，选择将 PDE[769] 自映射到页目录本身所在的 0x101000 帧，这样页目录自己也被当成一张页表来用，它管理的恰好是全部 1024 张页表本身，共 4MB。这部分虚拟地址空间为 0xC0400000 ~ 0xC0800000，其中页目录所在的虚拟地址为 0xC0701000
PDE[770] ~ PDE[1023] 共 254 项依次映射内核其余的页表，覆盖 KERNEL_SPACE_START + 0x0800000 起的内核代码与数据空间

开启分页#

page tables 都准备就绪后，就可以打开 paging 了：

1
; 启用分页，并调整段寄存器与 GDT 到高地址空间
2
enable_page:
3
    sgdt [gdt_descriptor]
4

5
    ; 调整视频段描述符的基址
6
    ; +2 表示描述符表中的 base 偏移
7
    mov ebx, [gdt_descriptor + 2]
8
    ; 0x18 表示第三个GDT, 也就是视频段
9
    ; +4 是为了修改到基址的高位部分
10
    or dword [ebx + 0x18 + 4], KERNEL_SPACE_START
11

12
    ; 移动 GDT 到大于 KERNEL_SPACE_START 的位置
13
    ; +2 表示描述符表中的 base 偏移
14
    add dword [gdt_descriptor + 2], KERNEL_SPACE_START
15

16
    ; 将栈移动到内核空间 KERNEL_SPACE_START
17
    mov eax, [esp]
18
    add esp, KERNEL_SPACE_START
19
    mov [esp], eax
20

21
    ; 设置页目录地址到 CR3 寄存器
22
    mov eax, PAGE_DIR_PHYISCAL_ADDR
23
    mov cr3, eax
24

25
    ; 启动分页
26
    mov eax, cr0
27
    or  eax, CR0_PG
28
    mov cr0, eax
29

30
    ; 在分页模式下重新加载 GDT
31
    lgdt [gdt_descriptor]
32

33
    ; 在分页模式下重新设置视频段
34
    mov ax, SELECTOR_VIDEO
35
    mov gs, ax
36

37
    ret

这里有两个容易遗漏的步骤。开启分页后，GDT 中段描述符的基址仍然指向低地址空间，需要用 lgdt 重新加载已经调整到 KERNEL_SPACE_START 之上的 GDT；同时 gs 段寄存器缓存了旧的视频段基址，需要重新加载 SELECTOR_VIDEO 让其指向高地址空间中的视频段。少了这两步，分页开启后立刻取指或写显存就会访问到错误的地址。