手写 MBR 引导程序：实模式磁盘读写与 Loader 加载

手写 MBR 引导程序，实模式下的磁盘读写与 Loader 加载#

计算机上电后，CPU 初始模式是实模式，此时地址宽度为 20 位，即最大地址空间 1MB。这 1MB 空间的划分是固定的，每一块都有规定的用途，被映射到不同的设备上：

起始	结束	大小	用途
`FFFF0`	`FFFFF`	`16 B`	`BIOS` 入口地址，此地址也属于 `BIOS` 代码，这 `16` 字节的内容用于执行跳转指令
`F0000`	`FFFEF`	`64KB-16B`	系统 `BIOS` 的地址范围实际上是 `F000-FFFFF`，上面是入口地址，所以单独列出
`C8000`	`EFFFF`	`160KB`	映射硬件适配器的 `ROM` 或内存映射式 `I/O`
`C0000`	`C7FFF`	`32KB`	显示适配器 `BIOS`
`B8000`	`BFFFF`	`32KB`	文本模式显示适配器
`B0000`	`B7FFF`	`32KB`	黑白显示适配器
`A0000`	`AFFFF`	`64KB`	彩色显示适配器
`9F000`	`9FC00`	`1KB`	`EBDA(Extended BIOS Data Area)` 扩展 `BIOS` 数据区
`7E00`	`9FBFF`	`≈608KB`	可用区域
`7C00`	`7DFF`	`512B`	`MBR` 被 `BIOS` 加载区域
`500`	`7BFF`	`≈30KB`	可用区域
`400`	`4FF`	`256B`	`BIOS Data Area`
`000`	`3FF`	`1KB`	`Interrupt Vector Table` 中断向量表

Note

为什么 MBR 被加载到 0x7C00？这是 IBM PC 5150 BIOS 的历史遗留约定。当年 DOS 1.0 需要 32KB 内存运行，0x7C00 正好是 32KB 减去 512 字节（MBR 大小）再减去 16 字节（BIOS 参数块）的位置。所有 x86 BIOS 兼容实现都沿用了这个地址，否则现有的操作系统和引导程序将无法启动。

这张表直接影响后续的内存规划。0x000 到 0x3FF 是中断向量表，任何中断调用都依赖它，绝对不能覆盖；0x400 到 0x4FF 存储 BIOS 内部数据；0xA0000 以上被显存和各种 ROM 占据。真正可供 MBR 和 Loader 使用的安全区域只有两块：0x500 到 0x7BFF（约 30KB）和 0x7E00 到 0x9FBFF（约 608KB）。MBR 自身被加载到 0x7C00，占用了其中 512 字节，所以 0x7C00 以下的区域可以安全地用作栈空间，而 0x7E00 以上则有充足的空间放置 Loader 和内核。

环境准备#

实验环境推荐使用 Linux + QEMU，Windows 用户可以使用 VirtualBox。此外需要 nasm（汇编器）、dd（写入镜像）和 hexdump（检查虚拟磁盘内容）三个工具。

开始编码 MBR#

现在编写的是电脑加电后运行的第一段代码。MBR 只有 512 字节，其中最后两个字节还必须留作引导签名 0xAA55，实际可用空间仅 510 字节。这点空间不可能容纳任何有意义的操作系统代码，所以 MBR 的唯一职责就是从磁盘读取更大的 Loader 程序到内存，然后把控制权交给它。整个实现分三步推进：先让 MBR 能在屏幕上打印字符，再加入磁盘读取功能，最后完成 Loader 加载与跳转。

内存规划方面，将 0x7C00 以下的区域作为栈空间（栈从高地址向低地址增长，MBR 在 0x7C00，栈顶设在 0x7C00 正好向下延伸不冲突），Loader 放在 0x8000，紧挨 MBR 之后，中间隔 512 字节的间隙，既不会覆盖 MBR 自身，又留出了栈的余量。

从 Hello MBR 开始#

首先创建一个 mbr.S 文件：

1
bits 16
2
org 0x7C00
3

4
start:
5
    call clear_screen     ; 调用清屏函数
6
    mov si, msg
7
    call print_string
8
    jmp $                 ; 无限循环
9

10
; ------------------------------
11
; 清屏 + 重置光标函数
12
; ------------------------------
13
clear_screen:
14
    ; 清屏
15
    mov ax, 0x0600        ; AH=06h 滚屏，AL=0 清屏
16
    mov bh, 0x07          ; 属性（白字黑底）
17
    mov cx, 0x0000        ; 左上角 (0,0)
18
    mov dx, 0x184F        ; 右下角 (24,79)
19
    int 0x10
20

21
    ; 重置光标到左上角
22
    mov ah, 0x02          ; 设置光标位置
23
    mov bh, 0x00          ; 显示页0
24
    mov dh, 0x00          ; 行=0
25
    mov dl, 0x00          ; 列=0
26
    int 0x10
27
    ret
28

29
; ------------------------------
30
; 打印字符串函数
31
; DS:SI 指向字符串，以 0 结尾
32
; ------------------------------
33
print_string:
34
    lodsb                 ; 取下一个字符到 AL
35
    or al, al             ; 判断是否为 0
36
    jz .done
37
    mov ah, 0x0E          ; BIOS 打印字符
38
    mov bh, 0x00          ; 显示页0
39
    int 0x10
40
    jmp print_string
41
.done:
42
    ret
43

44
; ------------------------------
45
; 数据区
46
; ------------------------------
47
msg db "hello mbr", 0
48

49
; ------------------------------
50
; 填充 & MBR 签名
51
; ------------------------------
52
times 510 - ($ - $$) db 0
53
dw 0xAA55

通过 nasm 将它编译成二进制文件：

1
nasm mbr.S

然后需要将编译好的 Hello MBR 二进制写入虚拟磁盘，以便虚拟机加载和执行。

1
# Windows
2
$ diskpart
3
$ create vdisk file = C:\hello.vhd maximum = 10 type=fixed

1
# Linux
2
$ qemu-img create -f vpc -o subformat=fixed hello.vhd 10M

Note

这里使用固定大小的虚拟磁盘是因为动态大小的虚拟磁盘文件在头部和尾部都会存在一些元信息，使用 dd 命令写入二进制会破坏虚拟磁盘格式，而固定大小的虚拟磁盘只有尾部有元信息。可以通过形如 hexdump -C hello.vhd 的命令查看虚拟磁盘的十六进制内容，观察是否包含头尾元信息。

然后通过 dd 命令将二进制写入虚拟磁盘：

1
# if 表示输入
2
# of 表示输出
3
# bs 表示读写块大小
4
# count 表示复制的块数量
5
# conv=notrunc 表示不截断清除后面的内容
6
$ dd if=mbr of=hello.vhd bs=512 count=1 conv=notrunc

最后通过 hexdump 命令查看写入后的虚拟磁盘内容：

1
$ hexdump -C hello.vhd
2
00000000  e8 08 00 be 31 7c e8 1a  00 eb fe b8 00 06 b7 07  |....1|..........|
3
00000010  b9 00 00 ba 4f 18 cd 10  b4 02 b7 00 b6 00 b2 00  |....O...........|
4
00000020  cd 10 c3 ac 08 c0 74 08  b4 0e b7 00 cd 10 eb f3  |......t.........|
5
00000030  c3 68 65 6c 6c 6f 20 6d  62 72 00 00 00 00 00 00  |.hello mbr......|
6
00000040  00 00 00 00 00 00 00 00  00 00 00 00 00 00 00 00  |................|
7
*
8
000001f0  00 00 00 00 00 00 00 00  00 00 00 00 00 00 55 aa  |..............U.|
9
00000200  00 00 00 00 00 00 00 00  00 00 00 00 00 00 00 00  |................|
10
*
11
00a07000  63 6f 6e 65 63 74 69 78  00 00 00 02 00 01 00 00  |conectix........|
12
00a07010  ff ff ff ff ff ff ff ff  31 df 9c 37 71 65 6d 75  |........1..7qemu|
13
00a07020  00 05 00 03 57 69 32 6b  00 00 00 00 00 a0 70 00  |....Wi2k......p.|
14
00a07030  00 00 00 00 00 a0 70 00  01 2e 04 11 00 00 00 02  |......p.........|
15
00a07040  ff ff e7 91 cb 36 5a 89  14 05 4c 0b b2 28 90 f6  |.....6Z...L..(..|
16
00a07050  00 8c 12 5e 00 00 00 00  00 00 00 00 00 00 00 00  |...^............|
17
00a07060  00 00 00 00 00 00 00 00  00 00 00 00 00 00 00 00  |................|
18
*
19
00a07200

可以看到前面的内容即是通过 dd 写入的 mbr 二进制，55 aa 是 MBR 引导签名，后面星号后面的内容则是虚拟磁盘的尾部元信息（conectix 是 VHD 格式的固定标识）。

Windows 用户可能需要从 dd.exe 下载 dd 工具，从 hexdump 下载 hexdump 工具。

最后通过虚拟机程序加载虚拟硬盘，即可看到最终效果。

对于 Windows 用户，可以通过 VirtualBox 新建虚拟机，类型和版本都选 other，最后虚拟硬盘选择制作的 hello.vhd，即可进行开机查看效果： HelloMBR-for-virtualbox

对于 Linux 用户，可以通过下面的命令查看效果：

1
$ qemu-system-i386 -drive file=hello.vhd,format=vpc -nographic

正常情况下，控制台会输出字符串：

1
hello mbr

Note

qemu-system-i386 使用 -nographic 选项后，是通过串口重定向（ttyS0）到终端的，无图形界面。所以无法直接通过写显存（B800）的方式打印字符。若想避免这一限制，可以使用 -vnc :0 选项替代，但需要下载 realvnc 客户端充当显示器。

支持读写磁盘内容的引导制作#

上一章节成功地让虚拟机加载并执行了我们编写的第一段代码。MBR（主引导扇区记录）是计算机开机后系统自动访问的第一个扇区程序，由于这段程序大小有限，通常需要从其他扇区读取更复杂的引导程序加载到内存中运行。因此第二步需要通过 MBR 读取磁盘其他扇区的内容。

MBR 被加载到 0x7C00 的位置，这次的任务是从磁盘中加载另一段程序（引导或内核）到内存。首先需要规划实模式下的内存使用。根据上图的可用区域，可以选择将 loader 加载到 0x8000 的位置。

本章不负责实现具体的 Loader，所以当前实现的 loader.S 程序仅实现打印任务：

1
bits 16
2
org 0x8000
3

4
    mov ax, 0xb800          ;显存位置
5
    mov es, ax
6

7
    mov byte[es: 0x00], 'L'
8
    mov byte[es: 0x01], 0x07
9
    mov byte[es: 0x02], 'O'
10
    mov byte[es: 0x03], 0x06
11
    mov byte[es: 0x04], 'A'
12
    mov byte[es: 0x05], 0x07
13
    mov byte[es: 0x06], 'D'
14
    mov byte[es: 0x07], 0x06
15
    mov byte[es: 0x08], 'E'
16
    mov byte[es: 0x09], 0x07
17
    mov byte[es: 0x0a], 'R'
18
    mov byte[es: 0x0b], 0x06
19
    jmp $

将这个程序通过 nasm 编译后写入磁盘的第二个扇区。现在开始改造 mbr.S，使其支持加载磁盘的第二个扇区并将 loader 程序载入内存运行：

1
bits 16
2
org 0x7c00
3

4
LOADER_BASE_ADDR        equ 0x8000      ; loader 所处的段地址
5
LOADER_SECTORS          equ 8           ; 需要读取的扇区数
6

7
    ; 初始化寄存器
8
    mov ax, cs
9
    mov ds, ax
10
    mov ss, ax
11
    mov fs, ax
12
    ; es 段赋0
13
    mov ax, 0
14
    mov es, ax
15
    ; 将 0x7c00 以下的区域作为栈
16
    mov sp, 0x7c00
17
    ; 显存段位置
18
    mov ax, 0xb800
19
    mov gs, ax
20

21
    ; 清空屏幕
22
    call cls
23

24
    ; 输出
25
    mov bx, hello_msg
26
    call print ; This will be written after the BIOS messages
27

28
    ;读loader
29
    mov dh,  LOADER_SECTORS   ; loader 扇区数，读8个扇区共4K空间
30
    mov dl,  0x80             ; 表示第一个磁盘
31
    mov bx,  LOADER_BASE_ADDR ; loader 的地址
32
    call disk_load
33

34
    ; 清空屏幕
35
    call cls
36
    jmp 0:LOADER_BASE_ADDR          ;跳转至 loader，也就是 0x8000
37

38
hello_msg: db "HELLO, MBR!", 0
39

40
; 清屏，并将屏幕设置为黑底白字
41
cls:
42
    mov ax, 0x0600       ; ah=06h(滚动窗口功能), al=00h(清空整个窗口)
43
    mov bx, 0x0700       ; bh=07h(空白行的显示属性: 黑底白字)
44
    mov cx, 0            ; ch=00h(左上角行号=0), cl=00h(左上角列号=0)
45
    mov dx, 184fh        ; dh=18h(右下角行号=24), dl=4fh(右下角列号=79)
46
    int 10h              ; 调用bios中断
47
    ret
48

49
; load 'dh' sectors from drive 'dl' into es:bx
50
disk_load:
51
    pusha
52
    ; reading from disk requires setting specific values in all registers
53
    ; so we will overwrite our input parameters from 'dx'. let's save it
54
    ; to the stack for later use.
55
    push dx
56

57
    mov ah, 0x02 ; ah <- int 0x13 function. 0x02 = 'read'
58
    mov al, dh   ; al <- number of sectors to read (0x01 .. 0x80)
59
    mov cl, 0x02 ; cl <- sector (0x01 .. 0x11)
60
                    ; 0x01 is our boot sector, 0x02 is the first 'available' sector
61
    mov ch, 0x00 ; ch <- cylinder (0x0 .. 0x3ff, upper 2 bits in 'cl')
62
    ; dl <- drive number. our caller sets it as a parameter and gets it from bios
63
    ; (0 = floppy, 1 = floppy2, 0x80 = hdd, 0x81 = hdd2)
64
    mov dh, 0x00 ; dh <- head number (0x0 .. 0xf)
65

66
    ; [es:bx] <- pointer to buffer where the data will be stored
67
    ; caller sets it up for us, and it is actually the standard location for int 13h
68
    int 0x13      ; bios interrupt
69
    jc disk_error ; if error (stored in the carry bit)
70

71
    pop dx
72
    cmp al, dh    ; bios also sets 'al' to the # of sectors read. compare it.
73
    jne sectors_error
74
    popa
75
    ret
76

77

78
disk_error:
79
    mov bx, disk_error_msg
80
    call print
81
    call print_nl
82
    mov dh, ah ; ah = error code, dl = disk drive that dropped the error
83
    call print_hex ; check out the code at http://stanislavs.org/helppc/int_13-1.html
84
    jmp disk_loop
85

86
sectors_error:
87
    mov bx, sectors_error_msg
88
    call print
89

90
disk_loop:
91
    jmp $
92

93
disk_error_msg: db "disk read error", 0
94
sectors_error_msg: db "incorrect number of sectors read", 0
95

96
; 打印函数
97
print:
98
    pusha
99
print_start:
100
    mov al, [bx]    ; 'bx' is the base address for the string
101
    cmp al, 0
102
    je done
103

104
    ; the part where we print with the bios help
105
    mov ah, 0x0e
106
    int 0x10        ; 'al' already contains the char
107

108
    ; increment pointer and do next loop
109
    add bx, 1
110
    jmp print_start
111

112
done:
113
    popa
114
    ret
115

116
; 打印换行函数
117
print_nl:
118
    pusha
119

120
    mov ah, 0x0e
121
    mov al, 0x0a ; newline
122
    int 0x10
123
    mov al, 0x0d ; carriage return
124
    int 0x10
125

126
    popa
127
    ret
128

129
; receiving the data in 'dx'
130
; For the examples we'll assume that we're called with dx=0x1234
131
print_hex:
132
    pusha
133

134
    mov cx, 0 ; our index variable
135

136
; Strategy: get the last char of 'dx', then convert to ASCII
137
; Numeric ASCII values: '0' (ASCII 0x30) to '9' (0x39), so just add 0x30 to byte N.
138
; For alphabetic characters A-F: 'A' (ASCII 0x41) to 'F' (0x46) we'll add 0x40
139
; Then, move the ASCII byte to the correct position on the resulting string
140
hex_loop:
141
    cmp cx, 4 ; loop 4 times
142
    je end
143

144
    ; 1. convert last char of 'dx' to ascii
145
    mov ax, dx ; we will use 'ax' as our working register
146
    and ax, 0x000f ; 0x1234 -> 0x0004 by masking first three to zeros
147
    add al, 0x30 ; add 0x30 to N to convert it to ASCII "N"
148
    cmp al, 0x39 ; if > 9, add extra 8 to represent 'A' to 'F'
149
    jle step2
150
    add al, 7 ; 'A' is ASCII 65 instead of 58, so 65-58=7
151

152
step2:
153
    ; 2. get the correct position of the string to place our ASCII char
154
    ; bx <- base address + string length - index of char
155
    mov bx, hex_out + 5 ; base + length
156
    sub bx, cx  ; our index variable
157
    mov [bx], al ; copy the ASCII char on 'al' to the position pointed by 'bx'
158
    ror dx, 4 ; 0x1234 -> 0x4123 -> 0x3412 -> 0x2341 -> 0x1234
159

160
    ; increment index and loop
161
    add cx, 1
162
    jmp hex_loop
163

164
end:
165
    ; prepare the parameter and call the function
166
    ; remember that print receives parameters in 'bx'
167
    mov bx, hex_out
168
    call print
169

170
    popa
171
    ret
172

173
hex_out:
174
    db '0x0000',0 ; reserve memory for our new string
175

176
    ; 签名
177
    times 510 - ($ - $$) db 0
178
    db 0x55, 0xaa

以上代码实现了 MBR 从磁盘 2 号扇区开始加载 8 个扇区的内容到内存 0x8000，并跳转到 0x8000 开始运行。通过下面的命令制作虚拟磁盘并将 mbr 和 loader 程序放到 0 扇区和 1 扇区：

1
$ nasm mbr.S
2
$ nasm loader.S
3
$ qemu-img create -f vpc -o subformat=fixed loader.vhd 10M
4
$ dd if=mbr of=loader.vhd bs=512 count=1 conv=notrunc
5
$ dd if=loader of=loader.vhd bs=512 seek=1 conv=notrunc,sync
6
$ hexdump -C loader.vhd
7
00000000  8c c8 8e d8 8e d0 8e e0  b8 00 00 8e c0 bc 00 7c  |...............||
8
00000010  b8 00 b8 8e e8 e8 33 00  65 c6 06 00 00 4d 65 c6  |......3.e....Me.|
9
00000020  06 01 00 0f 65 c6 06 02  00 42 65 c6 06 03 00 0f  |....e....Be.....|
10
00000030  06 04 00 52 65 c6  06 05 00 0f b6 08 b2 80  |e....Re.........|
11
00000040  bb 00 80 e8 14 00 ea 00  80 00 00 b8 00 06 bb 00  |................|
12
00000050  07 b9 00 00 ba 4f 18 cd  10 c3 60 52 b4 02 88 f0  |.....O....`R....|
13
00000060  b1 02 b5 00 b6 00 cd 13  72 07 5a 38 f0 75 12 61  |........r.Z8.u.a|
14
00000070  c3 bb 89 7c e8 43 00 e8  52 00 88 e6 e8 5a 00 eb  |...|.C..R....Z..|
15
00000080  06 bb 99 7c e8 33 00 eb  fe 64 69 73 6b 20 72 65  |...|.3...disk re|
16
00000090  61 64 20 65 72 72 6f 72  00 69 6e 63 6f 72 72 65  |ad error.incorre|
17
000000a0  63 74 20 6e 75 6d 62 65  72 20 6f 66 20 73 65 63  |ct number of sec|
18
000000b0  74 6f 72 73 20 72 65 61  64 00 60 8a 07 3c 00 74  |tors read.`..<.t|
19
000000c0  09 b4 0e cd 10 83 c3 01  eb f1 61 c3 60 b4 0e b0  |..........a.`...|
20
000000d0  0a cd 10 b0 0d cd 10 61  c3 60 b9 00 00 83 f9 04  |.......a.`......|
21
000000e0  74 1c 89 d0 83 e0 0f 04  30 3c 39 7e 02 04 07 bb  |t.......0<9~....|
22
000000f0  0b 7d 29 cb 88 07 c1 ca  04 83 c1 01 eb df bb 06  |.}).............|
23
00000100  7d e8 b6 ff 61 c3 30 78  30 30 30 30 00 00 00 00  |}...a.0x0000....|
24
00000110  00 00 00 00 00 00 00 00  00 00 00 00 00 00 00 00  |................|
25
*
26
000001f0  00 00 00 00 00 00 00 00  00 00 00 00 00 00 55 aa  |..............U.|
27
00000200  bd 00 7c 89 ec b8 00 b8  8e c0 26 c6 06 00 00 4c  |..|.......&....L|
28
00000210  26 c6 06 01 00 07 26 c6  06 02 00 4f 26 c6 06 03  |&.....&....O&...|
29
00000220  00 06 26 c6 06 04 00 41  26 c6 06 05 00 07 26 c6  |..&....A&.....&.|
30
00000230  06 06 00 44 26 c6 06 07  00 06 26 c6 06 08 00 45  |...D&.....&....E|
31
00000240  26 c6 06 09 00 07 26 c6  06 0a 00 52 26 c6 06 0b  |&.....&....R&...|
32
00000250  00 06 bb 97 80 e8 02 00  eb fe 60 8a 07 3c 00 74  |..........`..<.t|
33
00000260  09 b4 0e cd 10 83 c3 01  eb f1 61 c3 60 b4 0e b0  |..........a.`...|
34
00000270  0a cd 10 b0 0d cd 10 61  c3 00 00 00 00 00 00 00  |.......a........|
35
00000280  00 ff ff 00 00 00 9a cf  00 ff ff 00 00 00 92 cf  |................|
36
00000290  00 17 00 79 80 00 00 53  74 61 72 74 65 64 20 69  |...y...Started i|
37
000002a0  6e 20 31 36 2d 62 69 74  20 72 65 61 6c 20 6d 6f  |n 16-bit real mo|
38
000002b0  64 65 00 4c 6f 61 64 65  64 20 33 32 2d 62 69 74  |de.Loaded 32-bit|
39
000002c0  20 70 72 6f 74 65 63 74  65 64 20 6d 6f 64 65 00   | protected mode.|
40
000002d0  00 00 00 00 00 00 00 00  00 00 00 00 00 00 00 00  |................|
41
*
42
00000400  bd 00 7c 89 ec b8 00 b8  8e c0 26 c6 06 00 00 4c  |..|.......&....L|
43
00000410  26 c6 06 01 00 07 26 c6  06 02 00 4f 26 c6 06 03  |&.....&....O&...|
44
00000420  00 06 26 c6 06 04 00 41  26 c6 06 05 00 07 26 c6  |..&....A&.....&.|
45
00000430  06 06 00 44 26 c6 06 07  00 06 26 c6 06 08 00 45  |...D&.....&....E|
46
00000440  26 c6 06 09 00 07 26 c6  06 0a 00 52 26 c6 06 0b  |&.....&....R&...|
47
00000450  00 06 bb 97 80 e8 02 00  eb fe 60 8a 07 3c 00 74  |..........`..<.t|
48
00000460  09 b4 0e cd 10 83 c3 01  eb f1 61 c3 60 b4 0e b0  |..........a.`...|
49
00000470  0a cd 10 b0 0d cd 10 61  c3 00 00 00 00 00 00 00  |.......a........|
50
00000480  00 ff ff 00 00 00 9a cf  00 ff ff 00 00 00 92 cf  |................|
51
00000490  00 17 00 79 80 00 00 53  74 61 72 74 65 64 20 69  |...y...Started i|
52
000004a0  6e 20 31 36 2d 62 69 74  20 72 65 61 6c 20 6d 6f  |n 16-bit real mo|
53
000004b0  64 65 00 4c 6f 61 64 65  64 20 33 32 2d 62 69 74  |de.Loaded 32-bit|
54
000004c0  20 70 72 6f 74 65 63 74  65 64 20 6d 6f 64 65 00   | protected mode.|
55
000004d0  c3 01 83 c2 02 eb ed 61  c3 ed 61 c3 00 00 00 00  |.......a..a.....|
56
000004e0  00 00 00 00 00 00 00 00  00 00 00 00 00 00 00 00  |................|
57
*
58
00a07000  63 6f 6e 65 63 74 69 78  00 00 00 02 00 01 00 00  |conectix........|
59
00a07010  ff ff ff ff ff ff ff ff  30 17 8c 04 71 65 6d 75  |........0...qemu|
60
00a07020  00 05 00 03 57 69 32 6b  00 00 00 00 00 a0 70 00  |....Wi2k......p.|
61
00a07030  00 00 00 00 00 a0 70 00  01 2e 04 11 00 00 00 02  |......p.........|
62
00a07040  ff ff e5 37 98 ac aa 27  8b fe 42 d2 96 88 78 f4  |...7...'..B...x.|
63
00a07050  62 ed 38 53 00 00 00 00  00 00 00 00 00 00 00 00  |b.8S............|
64
00a07060  00 00 00 00 00 00 00 00  00 00 00 00 00 00 00 00  |................|
65
*
66
00a07200
67

68
$ qemu-system-i386 -drive file=loader.vhd,format=vpc -vnc :1

Note

上面的 hexdump 取自后续章节（开启保护模式）的 loader 产物。第 0 扇区是本章的 mbr.S；第 1、2 扇区（0x200、0x400）已经是下一章改造后的 loader.S，它带 GDT 与 Started in 16-bit real mode / Loaded 32-bit protected mode 两段提示字符串。本章最初的 loader.S 只把 LOADER 六个字母直接写进显存，不产生这些字符串。这里提前放出来是为了让读者直观看到 mbr 与 loader 在同一虚拟磁盘里的扇区布局。

最终效果如下图所示：

至此，一个运行在实模式下并且支持从磁盘读取 4KB 大小 Loader 的 MBR 程序编码完成，接下来的任务是完善这个 Loader，为加载和运行内核做好准备。

参考#

nasm 手册

手写 MBR 引导程序，实模式下的磁盘读写与 Loader 加载#

环境准备#

开始编码 MBR#

从 Hello MBR 开始#

支持读写磁盘内容的引导制作#

参考#

支持与分享